Fun with ThinkScript
Posted by robert
|
Re: Fun with ThinkScript October 14, 2016 12:55AM |
Quote
elovemer
however the dojis still do not show up on ES ... but they show up for spx
It does now. I left out an "=" sign on one of the lines. Thanks for pointing out my error.
- robert
Professional ThinkorSwim indicators for the average Joe
Edited 1 time(s). Last edit at 10/14/2016 12:56AM by robert.
|
Re: Fun with ThinkScript October 16, 2016 09:38AM |
Quote
Ralph53
Does anyone know how to script a stock's current spread? Thanks.
I myself have only seen it available as a market watch column script:
def spread = ask - bid; addLabel(yes, round(spread,2), color.current);
|
Re: Fun with ThinkScript October 20, 2016 09:44PM |
Can someone help me create this colored zone except with moving averages? I tried myself, but then made the realization that I do not know what I am doing. Thanks
robert Wrote:
-------------------------------------------------------
> > just trying to use the fullD line of StochRSI to
> create the colored zones
>
> ..... puts a new meaning to it's a art thing
>
>
> cute.
>
> I think this is what you are asking for.
>
> [i.imgur.com]
>
>
> def RSI = RSIWilder(length = 13).RSI;
> def highestRSI = Highest(RSI, 21);
> def lowestRSI = Lowest(RSI, 21);
> def RSIS = 100 * (RSI - lowestRSI) / (highestRSI -
> lowestRSI);
> def "%K" = Average(rsis, 3);
> def "%D" = Average("%K", 5);
>
> def value1 = highestall(high);
> def value2 = lowestall(low);
> def neg = if "%D" < "%D"[1] then lowestall(low)
> else double.nan;
>
> addcloud(value1,value2,color.light_green);
> addcloud(value1,neg,color.pink);
>
robert Wrote:
-------------------------------------------------------
> > just trying to use the fullD line of StochRSI to
> create the colored zones
>
> ..... puts a new meaning to it's a art thing
>
>
> cute.
>
> I think this is what you are asking for.
>
> [i.imgur.com]
>
>
> def RSI = RSIWilder(length = 13).RSI;
> def highestRSI = Highest(RSI, 21);
> def lowestRSI = Lowest(RSI, 21);
> def RSIS = 100 * (RSI - lowestRSI) / (highestRSI -
> lowestRSI);
> def "%K" = Average(rsis, 3);
> def "%D" = Average("%K", 5);
>
> def value1 = highestall(high);
> def value2 = lowestall(low);
> def neg = if "%D" < "%D"[1] then lowestall(low)
> else double.nan;
>
> addcloud(value1,value2,color.light_green);
> addcloud(value1,neg,color.pink);
>
|
Re: Fun with ThinkScript October 22, 2016 08:39AM |
Quote
ACWE
Can someone help me create this colored zone except with moving averages? I tried myself, but then made the realization that I do not know what I am doing. Thanks
something like this? i referenced roberts e-charts script so you can decide if you want simple or exponential moving average setting. here's another roberts example which helps explain the basics of crossovers for reference.
input movAvg1_Length = 10;
input movAvg2_Length = 20;
input average_type = {default "SMA", "EMA"};
input showMovAvgLines = {default "yes", "no"};
def MA1;
def MA2;
switch (average_type) {
case "SMA":
MA1 = Average(close, movAvg1_Length);
MA2 = Average(close, movAvg2_Length);
case "EMA":
MA1 = ExpAverage(close, movAvg1_Length);
MA2 = ExpAverage(close, movAvg2_Length);
}
# Plot the moving average lines
plot ln1 = if !showMovAvgLines then MA1 else double.nan;
ln1.SetDefaultColor(CreateColor(111,183,214)); #blue
ln1.SetLineWeight(1);
ln1.HideBubble();
plot ln2 = if !showMovAvgLines then MA2 else double.nan;
ln2.SetDefaultColor(CreateColor(249,140,182)); #pink
ln2.SetLineWeight(1);
ln2.HideBubble();
# Plot the clouds
def value1 = highestall(high);
def value2 = lowestall(low);
def crossDn = if MA1 < MA2 then lowestall(low) else double.nan;
addcloud(value1,value2,color.light_green);
addcloud(value1,crossDn,color.pink);
|
Re: Fun with ThinkScript October 23, 2016 12:19PM |
Quote
rcmcfe
can it be altered to display Stochastics, instead of MA crossovers?
i was thinking robert had already shown an example of this but i didn't have any luck finding it. im not sure which version of stochastic you use, but below is an example of the standard tos stochasticfull script with roberts cloud script just simply added to the bottom.
declare lower;
# --- TD Ameritrade IP Company, Inc. (c) 2008-2016
# --- StochasticFull standard script
input over_bought = 80;
input over_sold = 20;
input KPeriod = 10;
input DPeriod = 10;
input priceH = high;
input priceL = low;
input priceC = close;
input slowing_period = 3;
input averageType = AverageType.SIMPLE;
def lowest_k = Lowest(priceL, KPeriod);
def c1 = priceC - lowest_k;
def c2 = Highest(priceH, KPeriod) - lowest_k;
def FastK = if c2 != 0 then c1 / c2 * 100 else 0;
plot FullK = MovingAverage(averageType, FastK, slowing_period);
plot FullD = MovingAverage(averageType, FullK, DPeriod);
plot OverBought = over_bought;
plot OverSold = over_sold;
FullK.SetDefaultColor(GetColor(5));
FullD.SetDefaultColor(GetColor(0));
OverBought.SetDefaultColor(GetColor(1));
OverSold.SetDefaultColor(GetColor(1));
# --- add roberts clouds
def value1 = 100;
def value2 = 0;
def neg = if FullK < FullD then 0 else Double.NaN;
AddCloud(value1, value2, Color.LIGHT_GREEN);
AddCloud(value1, neg, Color.PINK);
|
Re: Fun with ThinkScript October 23, 2016 01:00PM |
Quote
ACWE
On a 5 minute chart, as I scroll to the right, the price axis does not change. It's like the chart fits a High/Low scale.
try unselecting fit studies option found under settings:
Quote
ACWE
I also like to use HULL as a moving average on a subchart. Can you add that in as a third option to go along with SMA and EMA?
unfortunately i didn't have any luck combining all three into roberts script, so to make the hull avg type work i had to separate it into its own script. I'm still learning so maybe someone more experienced knows how to combine all 3 types. from best i can tell, i didn't see the hull definition shown under the learning center where "average" and "expaverage" are listed.
declare upper;
input movAvg1_Price = close;
input movAvg2_Price = close;
input movAvg1_Length = 10;
input movAvg2_Length = 20;
input movAvg1_Displace = 0;
input movAvg2_Displace = 0;
input showMovAvgLines = { default "yes","no"};
def HMA1 = MovingAverage(AverageType.HULL, movAvg1_Price, movAvg1_Length)[-movAvg1_Displace];
def HMA2 = MovingAverage(AverageType.HULL, movAvg2_Price, movAvg2_Length)[-movAvg2_Displace];
plot line1 = if !showMovAvgLines then HMA1 else double.nan;
line1.DefineColor("Up", GetColor(1));
line1.DefineColor("Down", GetColor(0));
line1.AssignValueColor(if HMA1 > HMA1[1] then line1.color("Up" ) else line1.color("Down" ));
plot line2 = if !showMovAvgLines then HMA2 else double.nan;
line2.DefineColor("Up", GetColor(1));
line2.DefineColor("Down", GetColor(0));
line2.AssignValueColor(if HMA2 > HMA2[1] then line2.color("Up" ) else line2.color("Down" ));
# Plot the clouds
def value1 = highestall(high);
def value2 = lowestall(low);
def crossDn = if HMA1 < HMA2 then lowestall(low) else double.nan;
addcloud(value1,value2,color.light_green);
addcloud(value1,crossDn,color.pink);
Edited 1 time(s). Last edit at 10/23/2016 01:06PM by mntman.
Sorry, only registered users may post in this forum.